multimediacollege, Adobe Authorized Training Centre

getCharBoundaries(charIndex:int):Rectangle
Returns a rectangle that is the bounding box of the character.

package
{
	import flash.display.MovieClip;
	import flash.events.MouseEvent;
	import flash.text.TextField;
 
	/**
	 * ...
	 * @author Alwyn Wymeersch
	 */
	public class Main extends MovieClip
	{
		public var content_txt:TextField;
		// we store all characters in an array to animate them
		private var letters:Array;
		// have we converted the textfield to seperate chars?
		public var exploded:Boolean = false;
 
		public function Main()
		{
			init();
		}
 
		private function init():void
		{
			stage.addEventListener(MouseEvent.MOUSE_UP, explodeText);
		}
 
		private function explodeText(e:MouseEvent):void
		{
			// see if we already converted to seperate textfields
			if (exploded)
			{
				animateText();
			}
			else
			{
				processTextfield(content_txt);
			}
		}
 
	}
 
}

private function processTextfield(targetField:TextField):void
{
	if (letters == null)
		letters = new Array();
 
	// retrieve the text from the textfield
	var txt:String = targetField.text;
	// get the length of the text
	var l:int = txt.length;			
 
	// don't forget to fetch the textformat so we can
	// apply this to the letters
	var format:TextFormat = targetField.getTextFormat(0, l);
 
	// loop over the characters
	for (var i:int = 0; i < l; i++)
	{
		// get the position of this character
		var rect:Rectangle = targetField.getCharBoundaries(i);
 
		if (rect)
		{
			// a class I've written to make things easier
			// all you have to do is pass the position in the textfield
			var ch:Character = new Character(rect.x + targetField.x, rect.y + targetField.y);
			// set the default format before setting text
			ch.defaultTextFormat = format;
			// set the text
			ch.text = txt.substr(i, 1);
			// set the char at it's original position
			ch.toOrigin();
 
			// add to our array for animation
			letters.push(ch);
 
			// add it to the displaylist
			addChild(ch);
		}
	}
	// and in the end, remove the original textfield
	removeChild(targetField);
 
	exploded = true;
 
	animateText();
}

package
{
	import flash.geom.Point;
	import flash.text.AntiAliasType;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
 
	/**
	 * ...
	 * @author Alwyn Wymeersch
	 */
	public class Character extends TextField
	{
		// store the original position of the letter
		public var originPoint:Point
 
		public function Character(originx:int, originy:int)
		{
			originPoint = new Point(originx, originy);
			this.autoSize = TextFieldAutoSize.LEFT;
			embedFonts = true;
			selectable = false;
			antiAliasType = AntiAliasType.ADVANCED;
		}
		// positions the letter at it's original position
		public function toOrigin():void
		{
			this.x = originPoint.x;
			this.y = originPoint.y;
		}
	}
 
}

private function animateText():void
{
 
	for each (var ch:Character in letters)
	{
		 //in this case we will position it on it's original position
		 //but you can also put it at a random position or fixed point
		 //if you want to have an implode effect.
		ch.toOrigin();
		ch.rotationX = 0;
		ch.rotationY = 0;
 
		 //animate to a random position with a random rotation
		TweenNano.to(ch, 1, { x:Math.random() * stage.stageWidth,
			y:Math.random() * stage.stageHeight,
			rotationX:Math.random() * 360,
			rotationY:Math.random() * 360,
			ease:Strong.easeOut
			} );
	}
}

// this function animates the letters from the center of the stage
private function animateText():void
{
	var i:int = 0;
	for each (var ch:Character in letters)
	{
		ch.x = stage.stageWidth/2;
		ch.y = stage.stageHeight / 2;
		ch.alpha = 0;
 
		// animate to a random position with a random rotation
		TweenNano.to(ch,1, { x:ch.originPoint.x,
			y:ch.originPoint.y,
			delay: i * .01,
			alpha: 1
			} );
 
		i++;
	}
}

// animates the letters from X axis rotation 90 to normal
private function animateText():void
{
	var i:int = 0;
	for each (var ch:Character in letters)
	{
		ch.toOrigin();
		ch.rotationX = 90;
		//ch.y += 20
		ch.alpha = 0;
 
		// animate to a random position with a random rotation
		TweenNano.to(ch,1, { x:ch.originPoint.x,
			rotationX:0,
			delay: i * .01,
			alpha: 1
			} );
 
		i++;
	}
}